Администрация сайта
Бухгалтерия предприятия и КОРП, редакция 3.0 (3.0.58.26)
1С:Предприятие 8.3 (8.3.10.2667)
Задача:
При закрытии месяца неверно списывают транспортные расходы (происходит расхождение сумм по бухгалтерскому и налоговому учету).
В справке расчете в графе 7 при ручном подсчете по формуле, получается иная сумма.
При закрытии января начальное сальдо транспортных расходов в налоговом учете ошибочно игнорируется.
Решение:
Ошибка зарегистрирована под номером 10191177.
Исправление планируется в релизе 3.0.58.42
Временное решение:
Для исправления текст процедуры РасчетСебестоимости.СоздатьВТ_СальдоКосвенныхРасходов
Если НачалоНалоговогоПериода = Неопределено
Или НачалоНалоговогоПериода >= НачалоМесяца(Период) Тогда
// До начала месяца организация не была плательщиком налога на прибыль.
ПлательщикНалогаНаПрибыль = Ложь;
КонецЕсли;
следует заменить на текст
Процедура СоздатьВТ_СальдоКосвенныхРасходов(МенеджерВременныхТаблиц, Период, Организация)
// Сальдо определяется на начало месяца
НачалоМесяца = НачалоМесяца(Период);
// На счетах косвенных расходов может остаться сальдо в двух случаях:
// 1. сальдо транспортных расходов
// 2. сальдо нормируемых расходов налогового учета
// Их поместим в СальдоКосвенныхРасходов.
//
// Сальдо транспортных расходов может быть перенесено с прошлого года.
// Поэтому транспортные расходы можно отражать только по тем счетам, по которым субконто СтатьяЗатрат не оборотное.
// Следовательно, сальдо таких расходов получить просто.
//
// Если организация уплачивает налог на прибыль, то дополнительно нужно получать данные о нормируемых расходах.
// Сальдо нормируемых расходов не переносится с прошлого года.
// Поэтому суммы таких расходов могут накапливаться на счетах, где СтатьяЗатрат - оборотное субконто.
// Следовательно, нужно обращаться к оборотам с начала налогового периода. Это сложнее.
Запрос = Новый Запрос;
Запрос.МенеджерВременныхТаблиц = МенеджерВременныхТаблиц;
Запрос.УстановитьПараметр("Организация", Организация);
Запрос.УстановитьПараметр("Период", НачалоМесяца);
Запрос.УстановитьПараметр("ПустоеПодразделение", БухгалтерскийУчетПереопределяемый.ПустоеПодразделение());
ПлательщикНалогаНаПрибыль = УчетнаяПолитика.ПлательщикНалогаНаПрибыль(Организация, Период);
НачалоНалоговогоПериода = Неопределено;
Если ПлательщикНалогаНаПрибыль Тогда
НачалоНалоговогоПериода = НалоговыйУчет.НачалоНалоговогоПериода(Период, Организация);
Если НачалоНалоговогоПериода = Неопределено
Или НачалоНалоговогоПериода > НачалоМесяца Тогда
// До начала месяца организация не была плательщиком налога на прибыль.
ПлательщикНалогаНаПрибыль = Ложь;
КонецЕсли;
КонецЕсли;
ТребуютсяОбороты = ПлательщикНалогаНаПрибыль И НачалоМесяца > НачалоНалоговогоПериода;
Если Не ТребуютсяОбороты Тогда
Запрос.Текст =
"ВЫБРАТЬ
| ХозрасчетныйОстатки.Счет КАК Счет,
| ЕСТЬNULL(ХозрасчетныйОстатки.Подразделение, &ПустоеПодразделение) КАК Подразделение,
| ХозрасчетныйОстатки.Субконто1 КАК Субконто1,
| ХозрасчетныйОстатки.Субконто2 КАК Субконто2,
| ХозрасчетныйОстатки.Субконто3 КАК Субконто3,
| ХозрасчетныйОстатки.СуммаОстаток КАК Сумма,
| ХозрасчетныйОстатки.СуммаНУОстаток КАК СуммаНУ,
| ХозрасчетныйОстатки.СуммаПРОстаток КАК СуммаПР,
| ХозрасчетныйОстатки.СуммаВРОстаток КАК СуммаВР
|ПОМЕСТИТЬ ВТ_СальдоКосвенныхРасходов
|ИЗ
| РегистрБухгалтерии.Хозрасчетный.Остатки(
| &Период,
| Счет В
| (ВЫБРАТЬ
| СчетаКосвенныхРасходов.Счет
| ИЗ
| СчетаКосвенныхРасходов),
| ,
| Организация = &Организация) КАК ХозрасчетныйОстатки";
Запрос.Выполнить();
Возврат;
КонецЕсли;
// В налоговом учете на конец месяца могут остаться остатки сверхнормативных расходов.
// Для того, чтобы в следующем месяце сопоставить эти расходы с нормативами,
// важно знать статьи, по которым они отражены.
// Но на счетах расходов статья затрат - оборотное субконто и при получении остатков на начало месяца
// статья неизвестна.
//
// Сверхнормативные расходы не могут остаться с предыдущего года.
// Поэтому, для того, чтобы получить остатки сверхнормативных расходов в разрезе статей затрат,
// достаточно обратиться к оборотам с начала года до текущего месяца.
//
// Здесь игнорируем КорСчет, поскольку он нужен для разделения
// - прямых и косвенных расходов
// - материальных иных расходов в бухгалтерском учете (по элементам затрат)
// При этом
// - все нормируемые расходы - косвенные, транспортные - прямые, то есть, делить их не надо
// - классификация расходов на материальные и прочие в налоговом учете своя, определяемая видом статьи,
// а не КорСчетом.
Запрос.УстановитьПараметр("НормируемыеРасходы", Перечисления.ВидыРасходовНУ.НормируемыеРасходы());
Запрос.УстановитьПараметр("НачалоНалоговогоПериода", НачалоНалоговогоПериода);
Запрос.УстановитьПараметр("ДоНачалаПериода", НачалоМесяца - 1);
Запрос.Текст =
"ВЫБРАТЬ
| ХозрасчетныйВидыСубконто.Ссылка КАК Счет,
| ХозрасчетныйВидыСубконто.НомерСтроки КАК НомерСубконто
|ПОМЕСТИТЬ ВТ_СчетаРасходовОборотныеСтатьиЗатрат
|ИЗ
| ПланСчетов.Хозрасчетный.ВидыСубконто КАК ХозрасчетныйВидыСубконто
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ СчетаКосвенныхРасходов КАК СчетаКосвенныхРасходов
| ПО ХозрасчетныйВидыСубконто.Ссылка = СчетаКосвенныхРасходов.Счет
|ГДЕ
| ХозрасчетныйВидыСубконто.ВидСубконто = ЗНАЧЕНИЕ(ПланВидовХарактеристик.ВидыСубконтоХозрасчетные.СтатьиЗатрат)
| И ХозрасчетныйВидыСубконто.ТолькоОбороты
| И ХозрасчетныйВидыСубконто.Суммовой
|
|ИНДЕКСИРОВАТЬ ПО
| НомерСубконто,
| Счет
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| СтатьиЗатрат.Ссылка КАК СтатьяЗатрат
|ПОМЕСТИТЬ ВТ_СтатьиЗатратНормируемые
|ИЗ
| Справочник.СтатьиЗатрат КАК СтатьиЗатрат
|ГДЕ
| СтатьиЗатрат.ВидРасходовНУ В(&НормируемыеРасходы)
|
|ИНДЕКСИРОВАТЬ ПО
| СтатьяЗатрат
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| ХозрасчетныйОбороты.Счет КАК Счет,
| ЕСТЬNULL(ХозрасчетныйОбороты.Подразделение, &ПустоеПодразделение) КАК Подразделение,
| ХозрасчетныйОбороты.Субконто1 КАК Субконто1,
| ХозрасчетныйОбороты.Субконто2 КАК Субконто2,
| ХозрасчетныйОбороты.Субконто3 КАК Субконто3,
| 0 КАК Сумма,
| ХозрасчетныйОбороты.СуммаНУОборотДт - ХозрасчетныйОбороты.СуммаНУОборотКт КАК СуммаНУ,
| ХозрасчетныйОбороты.СуммаНУОборотКт - ХозрасчетныйОбороты.СуммаНУОборотДт КАК СуммаПР,
| 0 КАК СуммаВР
|ПОМЕСТИТЬ ВТ_СальдоКосвенныхРасходов
|ИЗ
| РегистрБухгалтерии.Хозрасчетный.Обороты(
| &НачалоНалоговогоПериода,
| &ДоНачалаПериода,
| ,
| Счет В
| (ВЫБРАТЬ РАЗЛИЧНЫЕ
| СчетаРасходов.Счет
| ИЗ
| ВТ_СчетаРасходовОборотныеСтатьиЗатрат КАК СчетаРасходов
| ГДЕ
| СчетаРасходов.НомерСубконто = 1),
| ,
| Организация = &Организация
| И Субконто1 ССЫЛКА Справочник.СтатьиЗатрат
| И Субконто1 В
| (ВЫБРАТЬ
| ВТ_СтатьиЗатратНормируемые.СтатьяЗатрат
| ИЗ
| ВТ_СтатьиЗатратНормируемые),
| ,
| ) КАК ХозрасчетныйОбороты
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ХозрасчетныйОбороты.Счет,
| ЕСТЬNULL(ХозрасчетныйОбороты.Подразделение, &ПустоеПодразделение),
| ХозрасчетныйОбороты.Субконто1,
| ХозрасчетныйОбороты.Субконто2,
| ХозрасчетныйОбороты.Субконто3,
| 0,
| ХозрасчетныйОбороты.СуммаНУОборотДт - ХозрасчетныйОбороты.СуммаНУОборотКт,
| ХозрасчетныйОбороты.СуммаНУОборотКт - ХозрасчетныйОбороты.СуммаНУОборотДт,
| 0
|ИЗ
| РегистрБухгалтерии.Хозрасчетный.Обороты(
| &НачалоНалоговогоПериода,
| &ДоНачалаПериода,
| ,
| Счет В
| (ВЫБРАТЬ РАЗЛИЧНЫЕ
| СчетаРасходов.Счет
| ИЗ
| ВТ_СчетаРасходовОборотныеСтатьиЗатрат КАК СчетаРасходов
| ГДЕ
| СчетаРасходов.НомерСубконто = 2),
| ,
| Организация = &Организация
| И Субконто2 ССЫЛКА Справочник.СтатьиЗатрат
| И Субконто2 В
| (ВЫБРАТЬ
| ВТ_СтатьиЗатратНормируемые.СтатьяЗатрат
| ИЗ
| ВТ_СтатьиЗатратНормируемые),
| ,
| ) КАК ХозрасчетныйОбороты
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ХозрасчетныйОбороты.Счет,
| ЕСТЬNULL(ХозрасчетныйОбороты.Подразделение, &ПустоеПодразделение),
| ХозрасчетныйОбороты.Субконто1,
| ХозрасчетныйОбороты.Субконто2,
| ХозрасчетныйОбороты.Субконто3,
| 0,
| ХозрасчетныйОбороты.СуммаНУОборотДт - ХозрасчетныйОбороты.СуммаНУОборотКт,
| ХозрасчетныйОбороты.СуммаНУОборотКт - ХозрасчетныйОбороты.СуммаНУОборотДт,
| 0
|ИЗ
| РегистрБухгалтерии.Хозрасчетный.Обороты(
| &НачалоНалоговогоПериода,
| &ДоНачалаПериода,
| ,
| Счет В
| (ВЫБРАТЬ РАЗЛИЧНЫЕ
| СчетаРасходов.Счет
| ИЗ
| ВТ_СчетаРасходовОборотныеСтатьиЗатрат КАК СчетаРасходов
| ГДЕ
| СчетаРасходов.НомерСубконто = 3),
| ,
| Организация = &Организация
| И Субконто3 ССЫЛКА Справочник.СтатьиЗатрат
| И Субконто3 В
| (ВЫБРАТЬ
| ВТ_СтатьиЗатратНормируемые.СтатьяЗатрат
| ИЗ
| ВТ_СтатьиЗатратНормируемые),
| ,
| ) КАК ХозрасчетныйОбороты
|
|ОБЪЕДИНИТЬ ВСЕ
|
|ВЫБРАТЬ
| ХозрасчетныйОстатки.Счет,
| ЕСТЬNULL(ХозрасчетныйОстатки.Подразделение, &ПустоеПодразделение),
| ХозрасчетныйОстатки.Субконто1,
| ХозрасчетныйОстатки.Субконто2,
| ХозрасчетныйОстатки.Субконто3,
| ХозрасчетныйОстатки.СуммаОстаток,
| ХозрасчетныйОстатки.СуммаНУОстаток,
| ХозрасчетныйОстатки.СуммаПРОстаток,
| ХозрасчетныйОстатки.СуммаВРОстаток
|ИЗ
| РегистрБухгалтерии.Хозрасчетный.Остатки(
| &Период,
| Счет В
| (ВЫБРАТЬ
| СчетаКосвенныхРасходов.Счет
| ИЗ
| СчетаКосвенныхРасходов)
| И НЕ Счет В
| (ВЫБРАТЬ РАЗЛИЧНЫЕ
| ВТ_СчетаРасходовОборотныеСтатьиЗатрат.Счет
| ИЗ
| ВТ_СчетаРасходовОборотныеСтатьиЗатрат),
| ,
| Организация = &Организация) КАК ХозрасчетныйОстатки
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТ_СчетаРасходовОборотныеСтатьиЗатрат
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ ВТ_СтатьиЗатратНормируемые";
Запрос.Выполнить();
КонецПроцедуры